home *** CD-ROM | disk | FTP | other *** search
/ Software Vault: The Gold Collection / Software Vault - The Gold Collection (American Databankers) (1993).ISO / cdr47 / wasm223.zip / KEYSET.ASM < prev    next >
Assembly Source File  |  1993-05-04  |  7KB  |  238 lines
  1. ;================================================================
  2. ; KEYSET By Eric Tauck
  3. ;
  4. ; This program sets the caps lock, num lock, and scroll lock
  5. ; state.  The usage is: 
  6. ; 
  7. ;   KEYSET [CAPS ON | OFF] [NUM ON | OFF] [SCROLL ON | OFF] 
  8. ; 
  9. ; Example: 
  10. ; 
  11. ;   KEYSET CAPS ON SCROLL OFF
  12. ; 
  13. ; This turns the caps lock on and the scroll lock off.
  14. ;
  15. ; If you have keyboard LED's, they will only be updated if you are 
  16. ; using an AT class computer.  The keyboard codes as returned by 
  17. ; the BIOS will reflect the state changes regardless of the type 
  18. ; of computer being used. 
  19. ;
  20. ; This program makes use of the WASM library files.
  21.  
  22.         INCLUDE 'library\string.asm'
  23.         INCLUDE 'library\case1.asm'
  24.         INCLUDE 'library\case2.asm'
  25.         INCLUDE 'library\parms.asm'
  26.         INCLUDE 'library\message1.asm'
  27.  
  28. ;--- state change flags
  29.  
  30. C_SET   EQU     0000000000000001B       ;set caps lock
  31. N_SET   EQU     0000000000000010B       ;set num lock
  32. S_SET   EQU     0000000000000100B       ;set scroll lock
  33.  
  34. ;--- BIOS data area constants
  35.  
  36. C_BIT   EQU     01000000B       ;caps lock bit
  37. N_BIT   EQU     00100000B       ;num lock bit
  38. S_BIT   EQU     00010000B       ;scroll lock bit
  39.  
  40. BDATA_SEG       EQU     0040H   ;segment of target data area
  41. BDATA_OFF       EQU     0017H   ;offset of target data area
  42.  
  43. ;--- program entry
  44.  
  45.         mov     ax, OFFSET banner       ;banner address
  46.         call    MesPutL                 ;display
  47.  
  48.         sub     ah, ah          ;zero bits
  49.         sub     di, di          ;clear all flags
  50.         jmps    main2           ;enter loop
  51.  
  52. main1   mov     al, C_BIT               ;hardware bit
  53.         mov     bx, OFFSET clock        ;option string
  54.         mov     cx, C_SET               ;flag bit
  55.         call    checkopt                ;check if option
  56.         jc      main2                   ;jump if so
  57.  
  58.         mov     al, N_BIT               ;hardware bit
  59.         mov     bx, OFFSET nlock        ;option string
  60.         mov     cx, N_SET               ;flag bit
  61.         call    checkopt                ;check if option
  62.         jc      main2                   ;jump if so
  63.  
  64.         mov     al, S_BIT               ;hardware bit
  65.         mov     bx, OFFSET slock        ;option string
  66.         mov     cx, S_SET               ;flag bit
  67.         call    checkopt                ;check if option
  68.         jc      main2                   ;jump if so
  69.         jmp     error
  70.  
  71. main2   push    ax
  72.         call    ParGet          ;get next parameter
  73.         mov     si, ax
  74.         pop     ax
  75.         jnc     main1           ;loop back if availible
  76.  
  77.         or      di, di          ;check if any options
  78.         jz      help            ;jump if none
  79.  
  80. ;--- perform all settings, flags in DI and AH
  81.  
  82.         push    ds
  83.         mov     dx, BDATA_SEG   ;
  84.         mov     ds, dx          ;-- load address
  85.         mov     bx, BDATA_OFF   ;
  86.         mov     al, [bx]        ;load keyboard control byte
  87.  
  88. ;--- set caps lock
  89.  
  90.         test    di, C_SET       ;check if set caps lock
  91.         jz      main3
  92.         and     al, NOT C_BIT   ;zero bit
  93.         mov     dl, ah          ;load bit settings
  94.         and     dl, C_BIT       ;mask bit
  95.         or      al, dl          ;set bit on or off
  96.  
  97. ;--- set num lock
  98.  
  99. main3   test    di, N_SET       ;check if set num lock
  100.         jz      main4
  101.         and     al, NOT N_BIT   ;zero bit
  102.         mov     dl, ah          ;load bit settings
  103.         and     dl, N_BIT       ;mask bit
  104.         or      al, dl          ;set bit on or off
  105.  
  106. ;--- set scroll lock
  107.  
  108. main4   test    di, S_SET       ;check if set scroll lock
  109.         jz      main5
  110.         and     al, NOT S_BIT   ;zero bit
  111.         mov     dl, ah          ;load bit settings
  112.         and     dl, S_BIT       ;mask bit
  113.         or      al, dl          ;set bit on or off
  114.  
  115. ;--- finished
  116.  
  117. main5   mov     [bx], al
  118.         pop     ds
  119.  
  120.         mov     ax, 4C00H       ;exit function error code 0
  121.         int     21H             ;execute
  122.  
  123. ;--- no options, display help
  124.  
  125. help    mov     ax, OFFSET helpmes
  126.         call    MesPutL
  127.         mov     ax, 4CFFH
  128.         int     21H
  129.  
  130. ;--- invalid options, display error message
  131.  
  132. error   mov     ax, OFFSET errmes
  133.         call    MesPutL
  134.         mov     ax, 4CFFH
  135.         int     21H
  136.  
  137. ;========================================
  138. ; Try to match an option.
  139. ;
  140. ; In: SI= parameter string; BX= target
  141. ;     string; CX= flag bit; DI= current
  142. ;     flag bits; AH= current hardware
  143. ;     bits; AL= hardware bit.
  144. ;
  145. ; Out: DI & AH updated; CY= set if
  146. ;      option matched; SI= preserved.
  147.  
  148. checkopt PROC   NEAR
  149.         push    ax
  150.         push    cx
  151.         push    di
  152.  
  153.         push    bx
  154.         mov     ax, si
  155.         call    StrUpr          ;convert to uppercase
  156.         pop     bx
  157.         mov     ax, si
  158.         call    StrCmp          ;compare with target string
  159.         jc      chkopt2         ;jump if no match
  160.  
  161.         call    ParGet          ;get ON/OFF
  162.         jc      chkopt3         ;jump if error
  163.         mov     di, ax
  164.         call    StrUpr          ;convert to uppercase
  165.         mov     ax, di
  166.         mov     bx, OFFSET on_str
  167.         call    StrCmp                  ;check if ON
  168.         jnc     chkopt1                 ;jump if so
  169.         mov     ax, di
  170.         mov     bx, OFFSET off_str
  171.         call    StrCmp                  ;check if OFF
  172.         jc      chkopt3                 ;jump if not
  173.  
  174. ;--- found OFF
  175.  
  176.         call    dispopt         ;display
  177.         pop     di
  178.         pop     cx
  179.         pop     ax
  180.         or      di, cx          ;set flag bit
  181.         not     al              ;flip bits
  182.         and     ah, al          ;zero hardware bit
  183.         stc
  184.         ret
  185.  
  186. ;--- found ON
  187.  
  188. chkopt1 call    dispopt         ;display
  189.         pop     di
  190.         pop     cx
  191.         pop     ax
  192.         or      di, cx          ;set flag bit
  193.         or      ah, al          ;set hardware bit
  194.         stc
  195.         ret
  196.  
  197. ;--- string doesn't match
  198.  
  199. chkopt2 pop     di
  200.         pop     cx
  201.         pop     ax
  202.         clc
  203.         ret
  204.  
  205. ;--- error, no ON or OFF
  206.  
  207. chkopt3 jmp     error
  208.         ENDP
  209.  
  210. ;========================================
  211. ; Display the new state.
  212.  
  213. dispopt PROC    NEAR
  214.         mov     ax, si
  215.         call    MesPut
  216.         mov     ax, OFFSET ismes
  217.         call    MesPut
  218.         mov     ax, di
  219.         call    MesPutL
  220.         ret
  221.         ENDP
  222.  
  223. ;========================================
  224. ; Data.
  225.  
  226. clock   DB      'CAPS',0
  227. nlock   DB      'NUM',0
  228. slock   DB      'SCROLL',0
  229.  
  230. on_str  DB      'ON',0
  231. off_str DB      'OFF',0
  232.  
  233. banner  DB      13,10,'KeySet By Eric Tauck',0
  234. helpmes DB      'Usage: KEYSET [CAPS ON | OFF] [NUM ON | OFF]'
  235.         DB      ' [SCROLL ON | OFF]',0
  236. errmes  DB      'Error: run KEYSET without options for help',0
  237. ismes   DB      ' is ',0
  238.